Главная категория > Компьютеры, сканеры ШК, Клавиатуры, принтеры и ПО и т.д.
Рековери Win 8.1 из extHDD или DVD-RAM
Юр:
А бывает на оф сайтах образы рековери?
Я так понимаю, что главное найти все что нужно для бутманагера, а сам развертываемый образ содержится в swm-файлах (которые есть нарезка одного wim-файла из-за необходимости уместиться на DVD)? Если взять любой рековери образ, даже с семеркой, и заменить в нем swm-файлы из архива, процесс пойдет?
drfaust:
С офф. сайтов не видели, но возможно (у НР врядли).
Делали по другому - с рабочего той же конторы сливали один раздел - recovery, потом на венике делали такой же раздел(не меньше, на пустом венике - я так понял разметка не важна). Делали его активным и в диосе выставляли необходимые настройки (AHCI+UEFI). Каким-то чудом сразу стартовал recovery и делал "магазинный" веник (только раздел recovery был не там как обычно (у нас в начале диска, а сколько образова не видел - везде в конце)).
Так оживили пару асеров, но не более того - плюнули на гемор и стали ставить с 0.
Про образы с оффсайта говорил мой сослуживец, но я лично не видел ни разу.
Он ещё на 7ке и 8ке начал делать что-то вроде бэкапа - одна кнопка и вертается всё к тому моменту как ставил (с дровами, прогами, обновами, но погибают "фотки")
Юр:
Склеил я эти файлы в WIM, залил на винт, пошла установка, но остановилась при настройке компонентов, потому что захотела вот это
c:\System.sav\Util\TDCTWKs\HideCMD.vbs
c:\System.sav\Util\TDCTWKs\HideEXE.vbs
В итоге:
Установка Windows[/size]Не удалось выполнить синтаксический разбор или обработку файла ответов для автоматической установки[C:Windows\panther\unattend.xml] при проходе [auditUser].Параметры, указанные в файле ответов, не могут быть применены.Ошибка при обработке параметров для компонента[Microsoft-Windows-Deployment]
Какие-то сценарии развертывания. Причем как я вычитал у буржуев, The system.sav folder is specific to Compaq/HP systems. As there are differences in the restore procedure in different models of Compaq/HP system
Короче, нужна для процедур восстановления на различных моделях компаковских компьютеров. А эта директория ваще не образовалась при развертывании. Теперь чешу репу, откуда мне ее надыбать. осталось-то совсем малось. Может, где-то можно файл ответов подредактировать?
vvm:
apt-get install windows не канает ?
ведь всё так просто ))
Юр:
Ты не умничай. :) ) Если такой умный, скажи, куда конкретно нужно распаковать по этой команде
DISM /apply-image /imagefile:%CRM.BP.WIM% /index:%CRM.BP.RESTOREINDEX% /ApplyDir:%CRM.BP.DrvLetter%
%CRM.BP.DrvLetter% - 'это где?
Спойлер@ECHO OFF
REM FILE : PBR.cmd
REM VERSION: 2013-05-16
REM CYCLE : 2C14, 2014
REM USAGE : PBR.cmd
REM ====================================================
REM Setting Required Variable
REM ====================================================
SET CRM.ERR.NUM=0
SET CRM.ERR.MSG=NO ERROR DURING %~n0 PROCESSING
SET CRM.ESP.DrvLetter=P:
SET CRM.IP.DrvLetter=I:
SET CRM.WorkDir=%~dp0
SET CRM.WorkDrvLetter=%~d0
SET CRM.PostRM=\system.sav\util\PostRM\
SET CRM.PBR.TOOLPATH=%CRM.WorkDir%Tools\
SET CRM.PBR.Argu=%1
SET CRM.FLAG.Recovery=%CRM.UP.DrvLetter%%CRM.FLAG.UPPath%RImage.flg
SET CRM.FLAG.Reset=%CRM.UP.DrvLetter%%CRM.FLAG.UPPath%PBRReset.flg
SET CRM.FLAG.Refresh=%CRM.UP.DrvLetter%%CRM.FLAG.UPPath%PBRRefresh.flg
SET CRM.FLAG.BareMetal=%CRM.UP.DrvLetter%%CRM.FLAG.UPPath%PBRBareMetal.flg
SET CRM.FLAG.PBR=%CRM.UP.DrvLetter%%CRM.FLAG.UPPath%PBR.flg
SET CRM.ESP.WIM=%CRM.WorkDir%ESP.wim
SET CRM.ESP.LABEL=SYSTEM
SET CRM.ESP.FS=FAT32
SET CRM.ESP.GUID=c12a7328-f81f-11d2-ba4b-00a0c93ec93b
SET CRM.ESP.RESTOREINDEX=1
SET CRM.BP.WIM=%CRM.WorkDir%build.wim
SET CRM.BP.DrvLetter=B:
SET CRM.BP.RESTOREINDEX=1
SET CRM.UP.WIM=%CRM.WorkDir%install*.swm
SET CRM.RESERVE.PATH=%CRM.WorkDir%RM_Reserve\
IF "%CRM.PBR.Argu%"=="A" (
GOTO REFRESH_A
)
IF "%CRM.PBR.Argu%"=="B" (
GOTO REFRESH_B
)
IF "%CRM.PBR.Argu%"=="C" (
GOTO RESET_C
)
IF "%CRM.PBR.Argu%"=="D" (
GOTO RESET_D
)
REM ====================================================
REM PBR Refresh
REM ====================================================
:REFRESH_A
GOTO END
:REFRESH_B
ECHO [%TIME%][%~nx0] PBR Refresh
SET CRM.TMP=%CRM.FLAG.Refresh%
CALL :CreateFolder "%CRM.TMP%"
ECHO %CRM.PBR.Argu% >> %CRM.TMP%
IF EXIST %CRM.TMP% (
ECHO [%TIME%][%~nx0] Created Flag : %CRM.TMP%
)
GOTO POST_PBR
REM ====================================================
REM PBR Reset
REM ====================================================
:RESET_C
ECHO [%TIME%][%~nx0] PBR Reset - C
GOTO END
:RESET_D
ECHO [%TIME%][%~nx0] PBR Reset - D
REM ----------------------
REM ASSIGN ESP DRIVE LETTER
REM ----------------------
ECHO [%time%][%~nx0] Assign ESP Drive Letter
SET CRM.TMP.GUID=%CRM.ESP.GUID%
SET CRM.TMP.DrvLetter=%CRM.ESP.DrvLetter%
SET CRM.TMP.LOG=%CRM.UP.DrvLetter%%CRM.RM.LOG.UPPath%
ECHO [%time%][%~nx0] CMD.EXE /C "%CRM.PBR.TOOLPATH%AssignDrvLetterByGUID.cmd" %CRM.TMP.GUID% %CRM.TMP.DrvLetter% %CRM.TMP.LOG%
CMD.EXE /C "%CRM.PBR.TOOLPATH%AssignDrvLetterByGUID.cmd" %CRM.TMP.GUID% %CRM.TMP.DrvLetter% %CRM.TMP.LOG%
REM ----------------------
REM Check Reset or Bare Metal
REM ----------------------
SET CRM.TMP=%CRM.ESP.DrvLetter%\EFI\
IF NOT EXIST %CRM.TMP% (
ECHO [%time%][%~nx0] NOT Found %CRM.TMP% , DO PBR BARE METAL
ECHO [%TIME%][%~nx0] Create Flag
CALL :CreateFolder "%CRM.FLAG.BareMetal%"
ECHO [%TIME%][%~nx0] >> %CRM.FLAG.BareMetal%
GOTO R_BREAEMETAL
)
:R_RESET
ECHO [%TIME%][%~nx0] Create Reset Flag
SET CRM.TMP=%CRM.FLAG.Reset%
CALL :CreateFolder "%CRM.TMP%"
ECHO %CRM.PBR.Argu% >> %CRM.TMP%
IF EXIST %CRM.TMP% (
ECHO [%TIME%][%~nx0] Created Flag : %CRM.TMP%
)
REM ----------------------
REM Restore ESP : FORMAT ESP
REM ----------------------
SET CRM.FILE1=%CRM.ESP.DrvLetter%\EFI\Microsoft\Boot\BCD
SET CRM.FILE2=%CRM.ESP.DrvLetter%\EFI\Microsoft\Boot\bootmgfw.efi
IF EXIST %CRM.FILE1% (
IF EXIST %CRM.FILE2% (
ECHO [%time%][%~nx0] Found %CRM.FILE1% and %CRM.FILE2%
GOTO RESTORE_ESPWIM
)
)
ECHO [%time%][%~nx0] Can't Found %CRM.FILE1% and %CRM.FILE2%, Format ESP
REM ----------------------
REM Restore ESP : FORMAT ESP
REM ----------------------
ECHO [%time%][%~nx0] FORMAT ESP
SET CRM.TMP.DrvLetter=%CRM.ESP.DrvLetter%
SET CRM.TMP.FS=%CRM.ESP.FS%
SET CRM.TMP.LABEL=%CRM.ESP.LABEL%
SET CRM.TMP.LOG=%CRM.UP.DrvLetter%%CRM.RM.LOG.UPPath%
ECHO [%time%][%~nx0] CSCRIPT /NOLOGO "%CRM.PBR.TOOLPATH%FormatVol.vbs" %CRM.TMP.DrvLetter% %CRM.TMP.FS% %CRM.TMP.LABEL% %CRM.TMP.LOG%
CSCRIPT /NOLOGO "%CRM.PBR.TOOLPATH%FormatVol.vbs" %CRM.TMP.DrvLetter% %CRM.TMP.FS% %CRM.TMP.LABEL% %CRM.TMP.LOG%
IF %errorlevel% NEQ 0 (
SET CRM.ERR.NUM=795
SET CRM.ERR.MSG=FAIL: CSCRIPT /NOLOGO "%CRM.PBR.TOOLPATH%FormatVol.vbs" %CRM.TMP.DrvLetter% %CRM.TMP.FS% %CRM.TMP.LABEL% %CRM.TMP.LOG%
GOTO ENDPROCESS
)
ECHO [%time%][%~nx0] END
REM ----------------------
REM RESTORE ESP : Copy Windows backup BCD to ESP by BCDboot command
REM ----------------------
ECHO [%time%][%~nx0] RESTORE ESP
ECHO [%time%][%~nx0] X:\Windows\System32\BCDboot.exe %CRM.UP.DrvLetter%\Windows /s %CRM.ESP.DrvLetter% /f UEFI
X:\Windows\System32\BCDboot.exe %CRM.UP.DrvLetter%\Windows /s %CRM.ESP.DrvLetter% /f UEFI
IF %errorlevel% NEQ 0 (
SET CRM.ERR.NUM=795
SET CRM.ERR.MSG=FAIL: X:\Windows\System32\BCDboot.exe %CRM.UP.DrvLetter%\Windows /s %CRM.ESP.DrvLetter% /f UEFI
GOTO ENDPROCESS
)
REM ----------------------
REM RESTORE ESP : Restore ESP.wim
REM ----------------------
:RESTORE_ESPWIM
ECHO [%time%][%~nx0] Dism /apply-image /imagefile:"%CRM.ESP.WIM%" /index:%CRM.ESP.RESTOREINDEX% /ApplyDir:%CRM.ESP.DrvLetter%
Dism /apply-image /imagefile:"%CRM.ESP.WIM%" /index:%CRM.ESP.RESTOREINDEX% /ApplyDir:%CRM.ESP.DrvLetter%
IF %errorlevel% NEQ 0 (
SET CRM.ERR.NUM=795
SET CRM.ERR.MSG=FAIL: Dism /apply-image /imagefile:"%CRM.ESP.WIM%" /index:%CRM.ESP.RESTOREINDEX% /ApplyDir:%CRM.ESP.DrvLetter%
GOTO ENDPROCESS
)
ECHO [%TIME%][%~nx0] END
GOTO POST_PBR
:R_BREAEMETAL
REM ----------------------
REM Restore Build Partition
REM ----------------------
ECHO [%time%][%~nx0] Apply build.wim to BP
ECHO [%time%][%~nx0] DISM /apply-image /imagefile:%CRM.BP.WIM% /index:%CRM.BP.RESTOREINDEX% /ApplyDir:%CRM.BP.DrvLetter%
DISM /apply-image /imagefile:%CRM.BP.WIM% /index:%CRM.BP.RESTOREINDEX% /ApplyDir:%CRM.BP.DrvLetter%
IF %errorlevel% NEQ 0 (
SET CRM.ERR.NUM=795
SET CRM.ERR.MSG=FAIL: DISM /apply-image /imagefile:%CRM.BP.WIM% /index:%CRM.BP.RESTOREINDEX% /ApplyDir:%CRM.BP.DrvLetter%
GOTO ENDPROCESS
)
REM ----------------------
REM Restore Factory Update
REM ----------------------
SET CRM.FU.Source=%CRM.WorkDrvLetter%\sources\FactoryUpdate\
SET CRM.FU.Dest=%CRM.UP.DrvLetter%\system.sav\FactoryUpdate\
SET CRM.XCOPY.SRC=%CRM.FU.Source%
SET CRM.XCOPY.DEST=%CRM.FU.Dest%
IF NOT EXIST %CRM.XCOPY.DEST% (MKDIR %CRM.XCOPY.DEST%)
ECHO [%time%][%~nx0] CMD /C XCOPY /Y /I /E /S /R /H %CRM.XCOPY.SRC%*.* %CRM.XCOPY.DEST%
CMD /C XCOPY /Y /I /E /S /R /H %CRM.XCOPY.SRC%*.* %CRM.XCOPY.DEST%
IF %errorlevel% NEQ 0 (
SET CRM.ERR.NUM=003
SET CRM.ERR.MSG=COPY FACTORY UPDATE FAIL
GOTO ENDPROCESS
)
SET CRM.FU.SWM=%CRM.XCOPY.DEST%FactoryUpdate.SWM
SET CRM.FU.WIM=%CRM.XCOPY.DEST%FactoryUpdate.WIM
IF EXIST %CRM.FU.WIM% (
GOTO FU_WIM
)
ECHO [%time%][%~nx0] Dism /apply-image /imagefile:%CRM.FU.SWM% /swmfile:%CRM.XCOPY.DEST%FactoryUpdate*.swm /index:1 /applydir:%CRM.XCOPY.DEST%
Dism /apply-image /imagefile:%CRM.FU.SWM% /swmfile:%CRM.XCOPY.DEST%FactoryUpdate*.swm /index:1 /applydir:%CRM.XCOPY.DEST%
IF %errorlevel% NEQ 0 (
SET CRM.ERR.NUM=003
SET CRM.ERR.MSG=FAIL: Dism /apply-image /imagefile:%CRM.FU.SWM% /swmfile:%CRM.XCOPY.DEST%FactoryUpdate*.swm /index:1 /applydir:%CRM.XCOPY.DEST%
GOTO ENDPROCESS
)
ECHO [%time%][%~nx0] DEL /Q /F %CRM.XCOPY.DEST%FactoryUpdate*.swm
DEL /Q /F %CRM.XCOPY.DEST%FactoryUpdate*.swm
GOTO FU_END
:FU_WIM
ECHO [%time%][%~nx0] Dism /apply-image /imagefile:%CRM.FU.WIM% /index:1 /applydir:%CRM.XCOPY.DEST%
Dism /apply-image /imagefile:%CRM.FU.WIM% /index:1 /applydir:%CRM.XCOPY.DEST%
IF %errorlevel% NEQ 0 (
SET CRM.ERR.NUM=003
SET CRM.ERR.MSG=FAIL: Dism /apply-image /imagefile:%CRM.FU.WIM% /index:1 /applydir:%CRM.XCOPY.DEST% //%CRM.UP.DrvLetter%\system.sav\FactoryUpdate\
GOTO ENDPROCESS
)
ECHO [%time%][%~nx0] DEL /Q /F %CRM.XCOPY.DEST%FactoryUpdate.WIM
DEL /Q /F %CRM.XCOPY.DEST%FactoryUpdate.WIM //после распаковки удаляется сам WIM
REM ----------------------
REM Copy Build.wim
REM ----------------------
SET CRM.COPY.SRC=%CRM.BP.WIM%
SET CRM.COPY.DEST=%CRM.UP.DrvLetter%\RM\Image\
IF NOT EXIST %CRM.XCOPY.DEST% (MKDIR %CRM.XCOPY.DEST%)
ECHO [%time%][%~nx0] COPY /Y %CRM.COPY.SRC% %CRM.COPY.DEST%
COPY /Y %CRM.COPY.SRC% %CRM.COPY.DEST%
IF %errorlevel% NEQ 0 (
SET CRM.ERR.NUM=003
SET CRM.ERR.MSG=FAIL: COPY /Y %CRM.COPY.SRC% %CRM.COPY.DEST%
GOTO ENDPROCESS
)
REM ----------------------
REM Copy Install*.swm
REM ----------------------
SET CRM.COPY.SRC=%CRM.UP.WIM%
SET CRM.COPY.DEST=%CRM.UP.DrvLetter%\RM\Image\
IF NOT EXIST %CRM.XCOPY.DEST% (MKDIR %CRM.XCOPY.DEST%)
ECHO [%time%][%~nx0] COPY /Y %CRM.COPY.SRC% %CRM.COPY.DEST%
COPY /Y %CRM.COPY.SRC% %CRM.COPY.DEST%
IF %errorlevel% NEQ 0 (
SET CRM.ERR.NUM=003
SET CRM.ERR.MSG=FAIL: COPY /Y %CRM.COPY.SRC% %CRM.COPY.DEST%
GOTO ENDPROCESS
)
:POST_PBR
REM ----------------------
REM Return Files
REM ----------------------
ECHO [%time%][%~nx0] CSCRIPT.EXE /NOLOGO "%CRM.RESERVE.PATH%ReturnFile.vbs" "%CRM.RESERVE.PATH%Reserve.log" "%CRM.RESERVE.PATH%" %CRM.UP.DrvLetter%
CSCRIPT.EXE /NOLOGO "%CRM.RESERVE.PATH%ReturnFile.vbs" "%CRM.RESERVE.PATH%Reserve.log" "%CRM.RESERVE.PATH%" %CRM.UP.DrvLetter%
REM ----------------------
REM Create PBR.flg and RImage.flg
REM ----------------------
SET CRM.TMP=%CRM.FLAG.Recovery%
CALL :CreateFolder "%CRM.TMP%"
ECHO %CRM.PBR.Argu% >> %CRM.TMP%
IF EXIST %CRM.TMP% (
ECHO [%TIME%][%~nx0] Created Flag : %CRM.TMP%
)
SET CRM.TMP=%CRM.FLAG.PBR%
CALL :CreateFolder "%CRM.TMP%"
ECHO %CRM.PBR.Argu% >> %CRM.TMP%
IF EXIST %CRM.TMP% (
ECHO [%TIME%][%~nx0] Created Flag : %CRM.TMP%
)
:ENDPROCESS
REM ====================================================
REM ENDPROCESS - CALL HERE TO EXIT - IF WE HAVE AN ERROR THEN LOG IT
REM ====================================================
IF %CRM.ERR.NUM% NEQ 0 (
ECHO.
ECHO ******************************************************************************
ECHO * ERROR: %CRM.ERR.NUM%
ECHO * : %CRM.ERR.MSG%
ECHO ******************************************************************************
ECHO.
)
:END
ECHO [%~nx0] %date% %time%
ECHO ********** FINISH %~nx0 **********
ECHO RETURN CODE - %CRM.ERR.NUM%
REM EXIT THE SCRIPT AND RETURN THE ERROR LEVEL
EXIT /b %CRM.ERR.NUM%
:CreateFolder
SET CRM.FullPATH=%1
SET CRM.PATH=NONE
for /f "delims==" %%F in ("%CRM.FullPATH%") do (
SET CRM.PATH=%%~dpF
)
IF "%CRM.PATH%"=="NONE" (
ECHO [%time%][%~nx0] WARNING, Create %CRM.FullPATH% Fail
) ELSE (
IF NOT EXIST "%CRM.PATH%" (
ECHO [%time%][%~nx0] MKDIR "%CRM.PATH%"
MKDIR "%CRM.PATH%"
)
)
EXIT /B
Навигация
Перейти к полной версии